Arduino - 湿度传感器

在本节中,我们将学习如何将 Arduino 板与不同的传感器连接。我们将讨论以下传感器 -

  • 湿度传感器(DHT22)
  • 温度传感器(LM35)
  • 水质探测器传感器(简单水触发器)
  • PIR 传感器
  • 超声波传感器
  • 全球定位系统

湿度传感器(DHT22)

DHT-22(也称为 AM2302)是一种数字输出,相对湿度和温度传感器。它使用电容式湿度传感器和热敏电阻测量周围空气,并在数据引脚上发送数字信号。

在本例中,你将学习如何将此传感器与 Arduino UNO 配合使用。室温和湿度将打印到串行监视器上。

DHT-22 传感器

DHT-22 传感器

连接很简单。左边的第一个引脚为 3-5V 电源,第二个引脚连接到数据输入引脚,最右边的引脚连接到地。

技术细节

  • 功率 - 3-5V

  • 最大电流 - 2.5mA

  • 湿度 - 0-100%,准确度 2-5%

  • 温度 - 40 至 80°C,±0.5°C 精度

需要的组件

你将需要以下组件 -

  • 1×面包板
  • 1×Arduino Uno R3
  • 1×DHT22
  • 1×10K 欧姆电阻

程序

按照电路图并连接面包板上的组件,如下图所示。

湿度传感器电路连接

湿度传感器面包板

草图

在你的计算机上打开 Arduino IDE 软件。用 Arduino 语言编码将控制你的电路。单击“新建”打开新的草图文件。

草图

Arduino 代码

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

代码注意

DHT22 传感器有四个端子(Vcc,DATA,NC,GND),它们连接到电路板如下 -

  • 数据引脚为 Arduino 引脚号 2
  • Vcc 引脚至 5 伏 Arduino 板
  • GND 引脚连接到 Arduino 板的地
  • 我们需要在 DATA 和 Vcc 引脚之间连接 10k 欧姆电阻(上拉电阻)

完成硬件连接后,你需要将 DHT22 库添加到 Arduino 库文件中,如前所述。

结果

你将在串口监视器上看到温度和湿度显示,每 2 秒更新一次。